screen storymap:
    imagemap:
        ground "default_main_map.jpg"
        hover "full_hover.png"
        idle "made_choices.png"
        
        if first_choice_done:
            hotspot (283, 206, 271, 106) clicked Jump("first_choice")
        if sea_road:
            hotspot (11, 302, 265, 244) clicked Jump("sea_menu")
        if wood_road:
            hotspot (290, 316, 242, 230) clicked Jump("wood_menu")
        if stone_road:
            hotspot (560, 280, 213, 242) clicked Jump ("stone_menu")

screen sea_map:
    imagemap:
        ground "Sea_road_default.jpg"
        hover "Sea_Road_Hovers.png"
        idle "Sea_road_choices_made.png"
        
        if first_choice_done:
            hotspot (603, 1, 195, 81) clicked Jump("rewind_menu")
        if ship_choice_done:
            hotspot (280, 134, 231, 93) clicked Jump("sea_choice_a")
        if instrument_done:
            hotspot (103, 210, 245, 97) clicked Jump("sea_choice_b")
        if captain_done:
            hotspot (181, 300, 221, 126) clicked Jump("sea_choice_c")
        if potion:
            hotspot (84, 428, 160, 76) clicked Jump("tell_pirate")
        if tunnels:
            hotspot (246, 467, 153, 166) clicked Jump("dont_tell_pirate")
        if escape_choice_done:
            hotspot (456, 202, 244, 102) clicked Jump("sea_choice_d")
        if mermaid:
            hotspot (396, 300, 239, 116) clicked Jump("sea_choice_e")
        if flowers:
            hotspot (402, 494, 157, 76) clicked Jump("mermaid")
        if lyre:
            hotspot (12, 300, 165, 79) clicked Jump("play_lyre")
        if silent:
            hotspot (545, 420, 165, 95) clicked Jump("lost_at_sea")
        if swim:
            hotspot (632, 296, 150, 81) clicked Jump("swim")

screen wood_map:
    imagemap:
        ground "wood_road_default.jpg"
        hover "wood_road_hovers.png"
        idle "wood_road_choices_made.png"
        
        if first_choice_done:
            hotspot (588, 1, 211, 99) clicked Jump ("rewind_menu")
        if cottage_done:
            hotspot (286, 153, 219, 73) clicked Jump ("wood_choice_a")
        if grave_a_done:
            hotspot (28, 185, 234, 91) clicked Jump ("wood_choice_b")
        if grave_b_done:
            hotspot (504, 185, 230, 99) clicked Jump ("wood_choice_c")
        if trade_done:
            hotspot (281, 309, 220, 91) clicked Jump ("wood_choice_d")
        if give_knife:
            hotspot (153, 386, 171, 88) clicked Jump ("knife")
        if give_potion:
            hotspot (488, 397, 164, 91) clicked Jump ("potion")
        if gave_up:
            hotspot (5, 288, 183, 85) clicked Jump ("left_house")
        if left_meadow:
            hotspot (621, 288, 170, 99) clicked Jump ("lost_again")
        if guide:
            hotspot (276, 502, 242, 87) clicked Jump ("den_menu")

screen stone_map:
    imagemap:
        ground "stone_map_default.jpg"
        hover "stone_map_hovers.png"
        idle "stone_map_choices_made.png"
        
        if first_choice_done:
            hotspot (589, 1, 211, 108) clicked Jump ("rewind_menu")
        if cliff_done:
            hotspot (298, 115, 205, 102) clicked Jump ("stone_choice_a")
        if village_done:
            hotspot (460, 210, 207, 83) clicked Jump ("stone_choice_b")
        if cage_done:
            hotspot (399, 323, 209, 84) clicked Jump ("stone_choice_c")
        if follow_done:
            hotspot (121, 208, 226, 83) clicked Jump ("stone_choice_d")
        if tree_done:
            hotspot (190, 314, 198, 96) clicked Jump ("stone_choice_e")
        if knife:
            hotspot (68, 419, 171, 76) clicked Jump ("passed")
        if salve:
            hotspot (406, 484, 163, 80) clicked Jump ("heal")
        if fear:
            hotspot (541, 421, 174, 72) clicked Jump ("lyre_lies")
        if spoke:
            hotspot (622, 286, 166, 94) clicked Jump ("talk")
        if hesitate:
            hotspot (8, 282, 167, 111) clicked Jump ("lost_in_woods")
        if steal:
            hotspot (209, 485, 167, 87) clicked Jump ("egg_thief")

screen den_map:
    imagemap:
        ground "den_map_default.jpg"
        hover "den_map_hovers.png"
        idle "den_map_choices_made.png"
        
        if first_choice_done:
            hotspot (590, 1, 210, 92) clicked Jump ("rewind_menu")
        if trade_done:
            hotspot (1, 1, 200, 95) clicked Jump ("wood_menu")
        if enter_done:
            hotspot (281, 76, 231, 87) clicked Jump ("den_choice_a")
        if entrance_done:
            hotspot (482, 157, 207, 94) clicked Jump ("den_choice_b")
        if tunnels_done:
            hotspot (88, 153, 218, 103) clicked Jump ("den_choice_c")
        if ysa_done:
            hotspot (201, 292, 144, 90) clicked Jump ("den_choice_d")
        if den_done:
            hotspot (436, 284, 169, 92) clicked Jump ("den_choice_e")
        if heal_done:
            hotspot (362, 378, 154, 95) clicked Jump ("den_choice_f")
        if mother:
            hotspot (105, 428, 159, 96) clicked Jump ("mother_info")
        if stupid:
            hotspot (15, 254, 156, 109) clicked Jump ("fighter")
        if ran:
            hotspot (627, 255, 155, 107) clicked Jump ("runner")
        if betrayed:
            hotspot (571, 433, 161, 96) clicked Jump ("traitor")
        if complete:
            hotspot (323, 503, 150, 91) clicked Jump ("ending")

init python:
    
    sea_road = False
    wood_road = False
    stone_road = False
    first_choice_done = False
    
    #sea road choices
    
    ship_choice_done = False
    instrument_done = False
    captain_done = False
    escape_choice_done = False
    mermaid = False
    
    #sea road key items
    
    potion = False
    tunnels = False
    flowers = False
    
    #sea road bad ends
    
    lyre = False
    silent = False
    swim = False
    
    #wood road choices
    
    cottage_done = False
    grave_a_done = False
    grave_b_done = False
    trade_done = False
    
    #wood road bad ends
    
    give_knife = False
    give_potion = False
    gave_up = False
    left_meadow = False
    
    #wood road additional
    
    grave_flowers = False
    guide = False
    
    #stone road choices
    
    cliff_done = False
    village_done = False
    cage_done = False
    follow_done = False
    tree_done = False
    
    #stone road key items
    
    knife = False
    fear = False
    salve = False
    
    #stone road bad ends
    
    spoke = False
    hesitate = False
    steal = False
    
    #den choices
    
    enter_done = False
    entrance_done = False
    tunnels_done = False
    ysa_done = False
    den_done = False
    heal_done = False
    complete = False
    
    #den key items
    
    mother = False
    #the woman with the strings info is bundled with choice f being completed
    
    #den bad ends
    
    stupid = False
    ran = False
    betrayed = False
    
define d = Character("Denise", color="#a0db8e", what_font = "DeJaVuSans.ttf")
define i = Character("Instructions", what_font = "DeJaVuSans.ttf")

style say_label font "DeJaVuSans.ttf"

# General Images

image blank = "Unrestricted_Blank.jpg"
image page = "Unrestricted_Page.jpg"

# Intro Images

image intro_01 = "Unrestricted_intro_01.jpg"
image intro_02 = "Unrestricted_intro_02.jpg"
image intro_03 = "Unrestricted_intro_03.jpg"
image intro_04 = "Unrestricted_intro_04.jpg"

# Sea Road Images

image sea_01 = "Unrestricted_Sea_01.jpg"
image sea_02 = "Unrestricted_Sea_02.jpg"
image sea_03 = "Unrestricted_Sea_03.jpg"
image sea_04 = "Unrestricted_Sea_04.jpg"
image sea_05 = "Unrestricted_Sea_05.jpg"
image sea_06 = "Unrestricted_Sea_06.jpg"
image sea_07 = "Unrestricted_Sea_07.jpg"
image sea_08 = "Unrestricted_Sea_08.jpg"
image sea_09 = "Unrestricted_Sea_09.jpg"
image sea_10 = "Unrestricted_Sea_10.jpg"
image sea_11 = "Unrestricted_Sea_11.jpg"
image sea_12 = "Unrestricted_Sea_12.jpg"
image sea_13 = "Unrestricted_Sea_13.jpg"
image sea_14 = "Unrestricted_Sea_14.jpg"
image sea_15 = "Unrestricted_Sea_15.jpg"
image sea_16 = "Unrestricted_Sea_16.jpg"

# Stone Road Images

image stone_01 = "Unrestricted_Stone_01.jpg"
image stone_02 = "Unrestricted_Stone_02.jpg"
image stone_03 = "Unrestricted_Stone_03.jpg"
image stone_04 = "Unrestricted_Stone_04.jpg"
image stone_05 = "Unrestricted_Stone_05.jpg"
image stone_06 = "Unrestricted_Stone_06.jpg"
image stone_07 = "Unrestricted_Stone_07.jpg"
image stone_08 = "Unrestricted_Stone_08.jpg"
image stone_09 = "Unrestricted_Stone_09.jpg"
image stone_10 = "Unrestricted_Stone_10.jpg"
image stone_11 = "Unrestricted_Stone_11.jpg"
image stone_12 = "Unrestricted_Stone_12.jpg"
image stone_13 = "Unrestricted_Stone_13.jpg"
image stone_14 = "Unrestricted_Stone_14.jpg"
image stone_15 = "Unrestricted_Stone_15.jpg"
image stone_16 = "Unrestricted_Stone_16.jpg"

# Wood Road Images

image wood_01 = "Unrestricted_Wood_01.jpg"
image wood_02 = "Unrestricted_Wood_02.jpg"
image wood_03 = "Unrestricted_Wood_03.jpg"
image wood_04 = "Unrestricted_Wood_04.jpg"
image wood_05 = "Unrestricted_Wood_05.jpg"
image wood_06 = "Unrestricted_Wood_06.jpg"
image wood_07 = "Unrestricted_Wood_07.jpg"
image wood_08 = "Unrestricted_Wood_08.jpg"
image wood_09 = "Unrestricted_Wood_09.jpg"
image wood_10 = "Unrestricted_Wood_10.jpg"
image wood_11 = "Unrestricted_Wood_11.jpg"
image wood_12 = "Unrestricted_Wood_12.jpg"
image wood_13 = "Unrestricted_Wood_13.jpg"
image wood_14 = "Unrestricted_Wood_14.jpg"

# Den Images

image den_01 = "Unrestricted_Den_01.jpg"
image den_02 = "Unrestricted_Den_02.jpg"
image den_03 = "Unrestricted_Den_03.jpg"
image den_04 = "Unrestricted_Den_04.jpg"
image den_05 = "Unrestricted_Den_05.jpg"
image den_06 = "Unrestricted_Den_06.jpg"
image den_07 = "Unrestricted_Den_07.jpg"
image den_08 = "Unrestricted_Den_08.jpg"
image den_09 = "Unrestricted_Den_09.jpg"
image den_10 = "Unrestricted_Den_10.jpg"
image den_11 = "Unrestricted_Den_11.jpg"
image den_12 = "Unrestricted_Den_12.jpg"
image den_13 = "Unrestricted_Den_13.jpg"
image den_14 = "Unrestricted_Den_14.jpg"
image den_15 = "Unrestricted_Den_15.jpg"
image den_16 = "Unrestricted_Den_16.jpg"
image den_17 = "Unrestricted_Den_17.jpg"
image den_18 = "Unrestricted_Den_18.jpg"

# Ending Images

image end_01 = "Unrestricted_End_01.jpg"
image end_02 = "Unrestricted_End_02.jpg"
image end_03 = "Unrestricted_End_03.jpg"
image end_04 = "Unrestricted_End_04.jpg"
image end_05 = "Unrestricted_End_05.jpg"

label start:
    
    scene blank
    
    d "*sigh*"
    d "What am I going to do?"
    d "My editor wants my story by the end of the week..."
    d "And I've barely written anything..."
    d "..."
    d "Ok, let's go over what I have again..."
    
    scene intro_01
    
    d "Dragons...how original..."
    
    scene blank
    
    d "And that's where it ends since I have NO IDEA what to write next!"
    d "..."
    d "I don't have time for this...I just have to start writing and put down everything that comes to mind."
    d "I can edit it later..."
    
    "Denise is an author suffering from writer's block."
    "Your job is to help her finish her story by making choices and guiding her characters towards a conclusion."
    "But because this is all happening in Denise's head, she can always rethink choices when they don't go the way she planned!"
    "As the player you have the ability to make Denise go back and rethink a choice when things don't work out."
    "Luckily, she's keeping track of everything she writes in a chart."
    "Anytime Denise hits writer's block, use the charts to have her 'REWRITE SOMETHING' in order to go back and try something else. Sometimes this will give her ideas that will help her get past her blocks."
    "This will in turn unlock choices that may have been previously unavailable."
    "So make a habit of exploring and revisiting all the branches on the charts to see if Denise has any new ideas."
    "Good luck!"
    
    d "Alright where were we...?"
    
    scene intro_02
    
    d "Do dragons talk? They do now."
    
    scene intro_03
    
    d "It only took me two days and 26 google searches to come up with a name for that dragon."
    
    scene intro_04
    
    d "Uh...what should happen next?"
    
label first_choice:
    
    scene page
    
    menu:
        
        d "I wonder which way will get them to the Dragons' Den faster..."
    
        "Stone Road":
            $ first_choice_done = True
            $ stone_road = True
            jump stone_road
    
        "Wood Road":
            $ first_choice_done = True
            $ wood_road = True
            jump wood_road
    
        "Sea Road":
            $ first_choice_done = True
            $ sea_road = True
            jump sea_road
        
        "Rewrite Something" if first_choice_done == True:
            jump rewind_menu

label wood_road:
    
    scene wood_01
    
    d "On a scale of one to Hansel and Grettle how sketchy is the witch's house?"
    
label wood_choice_a:
    
    scene page
    
    menu:
        
        d "Should they approach the house? If there's a witch inside it could be dangerous..."
        
        "Approach":
            $ cottage_done = True
            jump approach
        
        "Keep Walking":
            $ cottage_done = True
            jump leave
        
        "Rewrite Something":
            $ cottage_done = True
            jump wood_menu

label approach:

    scene wood_02
    
    d "Gotta love a good tragic backstory!"
    
    $ grave_flowers = True

label wood_choice_b:
    
    scene page
    
    menu:
        
        d "That grave is probably...definately...part of why the boy won't let them in..."
    
        "Find Flowers for the grave" if flowers == True:
            $ grave_a_done = True
            jump question
    
        "Leave":
            $ gave_up = True
            $ grave_a_done = True
            jump left_house
        
        "Rewrite Something":
            $ grave_a_done = True
            jump wood_menu

label question:
    
    scene wood_03
    
    d "It's a nice thing to do, ya know?"
    
    jump meadow

label meadow:
    
    scene wood_04
    
    d "I should get myself some flowers...brighten up the room and all."
    
    if grave_flowers == False: 
        
        jump notice_grave
        
    if grave_flowers == True:
        
        jump tribute

label notice_grave:
    
    scene wood_05
    
    d "Gotta love a good tragic backstory!"
    
    jump tribute

label tribute:
    
    scene wood_06
    
    d "Aaaaand we're in!"
    
    scene wood_07
    
    d "Obviously that's why...did I make that clear enough?"
    
    scene wood_08
    
    d "How to convince him...Hmmm..."

label wood_choice_d:
    
    scene page
    
    menu:
        
        d "There has to be something we can offer that will convince him..."
        
        "Trade Knife" if knife == True:
            $ give_knife = True
            $ trade_done = True
            jump knife
        
        "Trade Potion" if potion == True:
            $ give_potion = True
            $ trade_done = True
            jump potion
        
        "Trade both the Knife and the Potion" if knife == True and potion == True:
            $ guide = True
            $ trade_done = True
            jump to_the_den
            
        "Rewrite Something":
            $ trade_done = True
            jump wood_menu

label knife:
    
    scene wood_09
    
    d "Who fights dragons with a knife?"
    
    scene blank
    
    d "Let's offer him something else..."
    
    menu:
        
        "Rewrite Something":
            jump wood_menu

label potion:
    
    scene wood_10
    
    d "Damn he's stubborn."
    
    scene blank 
    
    d "No no, this doesn't feel right at all..."
    
    menu:
        
        "Rewrite Something":
            jump wood_menu

label left_house:
    
    scene wood_11
    
    d "And neither do I..."
    
    scene blank
    
    d "Let's try a different approach..."
    
    menu:
        
        "Rewrite that Part...":
            jump wood_menu

label leave:
    
    scene wood_12
    
    d "Baby dragons don't appreciate pretty flowers."
    
label wood_choice_c:
    
    scene page
    
    menu:
        
        d "I wonder if there's anything they could do with these flowers...?"
        
        "Pick flowers to use as an offering" if flowers == True:
            $ grave_b_done = True
            jump gather
        
        "Leave the flower patch":
            $ left_meadow = True
            $ grave_b_done = True
            jump lost_again
        
        "Rewrite Something":
            $grave_b_done = True
            jump wood_menu

label gather:
    
    scene wood_13
    
    d "Flowers for every occasion! Or so they say."
    
    jump meadow

label lost_again:
    
    scene wood_14
    
    d "And then she.......zzzzzz"
    
    scene blank
    
    d "zzzzzzzz....."
    d "Augh! That's it I'm making some coffee!"
    d "..."
    d "Alright where were we?"
    
    menu:
        
        "Rewrite that Part...":
            jump wood_menu
    
label sea_road:
    
    scene sea_01
    
    d "Nothing suspicious about random boats."
    
    scene sea_02
    
    d "Oh this girl has no survival instinct."
    
    scene sea_03
    
    d "Are sirens too cliched?"
    
label sea_choice_a:
    
    scene page
    
    menu:
        
        d "The sirens are about to crash the ship...should she save the pirates or save herself?"
        
        "Help the pirates":
            $ ship_choice_done = True
            jump help_pirates
        
        "Escape the Ship":
            $ ship_choice_done = True
            jump escape
            
        "Rewrite Something":
            $ ship_choice_done = True
            jump sea_menu

label help_pirates:
    
    scene sea_04
    
    d "...I had to look this up..."

label sea_choice_b:
    
    scene page
    
    menu:
        
        d "She needs to drown those sirens out, will the lyre work? Does she have time to find another instrument?"
        
        "Play the Lyre":
            $ instrument_done = True
            $ lyre = True
            jump play_lyre
        
        "Find Something Else":
            $ instrument_done = True
            jump find_trumpet
        
        "Rewrite Something":
            $ instrument_done = True
            jump sea_menu

label play_lyre:
    
    scene sea_05
    
    d "Ok wait wait..."
    
    scene blank
    
    d "Hold on this is getting kinda dangerous here..."
    d "This is supposed to be a children's book, I can't let the ship crash!"
    d "Let's try something else..."
    
    menu:
        "Rewrite that Part":
            jump sea_menu

label find_trumpet:
    
    scene sea_06
    
    d "They are definitely musically inclined pirates."
    
    scene sea_07
    
    d "He's a pretty nice pirate. I bet he has a tragic backstory. Oh I should write him one!"

label sea_choice_c:
    
    scene page
    
    menu:
        
        d "To tell the pirate your life story...or not to tell...THAT is the question!"
        
        "Tell":
            $ captain_done = True
            $ potion = True
            jump tell_pirate
        
        "Don't Tell":
            $ captain_done = True
            $ tunnels = True
            jump dont_tell_pirate
        
        "Rewrite Something":
            $ captain_done = True
            jump sea_menu

label tell_pirate:
    
    scene sea_08
    
    d "A POTION...Oh! I know..."
    
    scene sea_09
    
    d "Now what indeed..."
    
    scene blank
    
    d "Hmmm...ok but at least that gave me some ideas!"
    
    menu:
        "Rewrite that part":
            jump sea_menu

label dont_tell_pirate:
    
    scene sea_10
    
    d "TUNNELS...oh! What if..."
    
    scene sea_09
    
    d "They're lost...I'm lost..."
    
    scene blank
    
    d "Hmmmm...ok but at least that gave me some ideas!"
    
    menu:
        "Rewrite that part":
            jump sea_menu

label escape:
    
    scene sea_11
    
    d "They have lifeboats on pirate ships right?"

label sea_choice_d:
    
    scene page
    
    menu:
        
        d "They have to hurry and get off this ship...what's the best method?"
    
        "Take the Lifeboat":
            $ escape_choice_done = True
            jump lifeboat
    
        "Swim":
            $ swim = True
            $ escape_choice_done = True
            jump swim
        
        "Rewrite Something":
            $ escape_choice_done = True
            jump sea_menu

label lifeboat:
    
    scene sea_12
    
    d "First sirens now mermaids? What's next?!"

label sea_choice_e:
    
    scene page
    
    menu:
        
        d "Why does the mermaid want to know what happened?"
        
        "Tell the Mermaid":
            $ mermaid = True
            $ flowers = True
            jump mermaid
        
        "Don't Tell":
            $ silent = True
            $ mermaid = True
            jump lost_at_sea
        
        "Rewrite Something":
            $ mermaid = True
            jump sea_menu

label mermaid:
    
    scene sea_13
    
    d "Hmm...FLOWERS...what if..."
    
    scene sea_14
    
    d "......."
    
    scene blank
    
    d "ZZzzzzzzz..."
    d "Zzzzz..."
    d "Zzz...huh...?"
    d "Oh shoot! Where were we!?"
    
    menu:
        "Rewrite something":
            jump sea_menu

label lost_at_sea:
    
    scene sea_15
    
    d "That's not good..."
    
    scene blank
    
    d "Uuuuuh..."
    d "Let's try that again..."
    
    menu:
        "Rewrite Something":
            jump sea_menu

label swim:
    
    scene sea_16
    d "Uh wait..."
    
    scene blank 
    
    d "STOP!"
    d "Stop stop stop, we can't kill the whelp!"
    
    menu:
        "Rewrite Something":
            jump sea_menu

label stone_road:
    
    scene stone_01
    
    d "The rules of fantasy state there must be at least one troll!"
    
label stone_choice_a:
    
    scene page
    
    menu:
        
        d "If she hangs on...the troll will get her...if she let's go...will she survive the fall?"
        
        "Hang On":
            $ cliff_done = True
            jump hang_on
        
        "Let Go":
            $ cliff_done = True
            jump let_go
        
        "Rewrite Something":
            $ cliff_done = True
            jump stone_menu

label hang_on:
    
    scene stone_02
    
    d "Satyrs...classic..."
    
    scene stone_03
    
    d "Wooden cage...wait, don't dragons breathe fire?"

label stone_choice_b:
    
    scene page
    
    menu:
        
        d "The satyrs are clearly trying to get information out of Reina...should she give it or not?"
        
        "Talk":
            $ village_done = True
            $ spoke = True
            jump talk
        
        "Don't Talk":
            $ village_done = True
            jump silent
        
        "Rewrite Something":
            $ village_done = True
            jump stone_menu

label talk:
    
    scene stone_04
    
    d "Not so sure about the way this is going..."
    
    scene blank
    
    d "...too violent for a kids' book?"
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label silent:
    
    scene stone_05
    
    d "I think I have a few ideas."

label stone_choice_c:
    
    scene page
    
    menu:
        
        d "Lyre thinks he has a way out...but Reina also has an idea...who to trust..."
        
        "Offer to Help":
            $ cage_done = True
            $ salve = True
            jump heal
        
        "Leave it to Lyre":
            $ cage_done = True
            $ fear = True
            jump lyre_lies
            
        "Rewrite Something":
            $ cage_done = True
            jump stone_menu

label lyre_lies:
    
    scene stone_06
    
    d "Are satyrs superstitious? Is that a thing? Can it be a thing?"
    
    scene stone_07
    
    d "Hmm...AFRAID OF WITCHES...how about..."
    
    scene blank
    
    d "Ok...but at least that gave me some ideas!"
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label heal:
    
    scene stone_08
    
    d "Being nice is usually the way to go."
    
    scene stone_09
    
    d "Things I ask myself: What kind of illness could a princess cure?"
    
    scene stone_10
    
    d "Oh! BURN OINTMENT...What if..."
    
    scene blank
    
    d "Oh shoot! I go them stuck again...ok but at least that gave me some ideas..."
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label let_go:
    
    scene stone_11
    
    d "Now centaurs? What's next? Elves?...No...no elves Denise you don't need elves..."

label stone_choice_d:
    
    scene page
    
    menu:
        
        d "The centaur wants them to follow him...should they?"
        
        "Follow him":
            $ follow_done = True
            jump glade
        
        "Stay Behind":
            $ follow_done = True
            $ hesitate = True
            jump lost_in_woods
        
        "Rewrite Something":
            $ follow_done = True
            jump stone_menu

label glade:
    
    scene stone_12
    
    d "Can princesses climb trees? That red-haired one with the bow could...I think..."

label stone_choice_e:
    
    scene page
    
    menu:
        
        d "The centaur had her climb this tree to get an egg. But what would be the best approach in this situation?"
        
        "Take the Egg":
            $ tree_done = True
            $ steal = True
            jump egg_thief
        
        "Leave the Egg":
            $ tree_done = True
            $ knife = True
            jump passed
            
        "Rewrite Something":
            $ tree_done = True
            jump stone_menu

label egg_thief:
    
    scene stone_13
    
    d "Now is a great time to mention that..."
    
    scene blank
    
    d "Let's go back and try that again..."
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label passed:
    
    scene stone_14
    
    d "Ah the ambiguous test of character...a classic."
    
    scene stone_15
    
    d "Hmmm a KNIFE...Oh! What if I..."
    
    scene blank 
    
    d "Oh...oops...I got them lost again..."
    d "But at least I got some ideas out of that!"
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label lost_in_woods:
    
    scene stone_16
    
    d "......."
    
    scene blank
    
    d "Zzzzzzz..."
    d "Zzzz...oH GODDAMIT! I need to fix my sleep schedule, ok where was I?"
    
    menu:
        
        "Rewrite that Part...":
            jump stone_menu

label to_the_den:
    
    scene den_01
    
    d "What's he going to do? Put the poison on the knife? ...Where are my notes I'm going to write that down."
    
    scene den_02
    
    d "There was totally a volcano there the whole time that nobody saw."
    
    scene den_03
    
    d "Thanks for the confidence, Kyle."
    
label den_choice_a:
    
    scene page
    
    menu:
        
        d "So we've got a heavily guaded entrance, and some confusing tunnels...how should we get in?"
        
        "Use the Tunnels" if tunnels == True:
            $ enter_done = True
            jump tunnel
    
        "Use the Entrance":
            $ enter_done = True
            jump entrance
    
        "Rewrite Something":
            $ enter_done = True
            jump den_menu

label tunnel:
    
    scene den_04
    
    d "Needs more chase scenes."

label den_choice_c:
    
    scene page
    
    menu:
        
        d "Their's a dragon coming after them...what should they do?"
        
        "Fight":
            $ stupid = True
            $ tunnels_done = True
            jump fighter
        
        "Hide":
            $ tunnels_done = True
            jump hiding_spot
        
        "Rewrite Something":
            $ tunnels_done = True
            jump den_menu

label fighter:
    
    scene den_05
    
    d "YOU CAN'T PUNCH A DRAGON!"
    
    scene blank
    
    d "...why do I keep trying to kill her?"
    
    menu:
        
        "Rewrite that Part...":
            jump den_menu

label hiding_spot:
    
    scene den_06
    
    d "Climbing through a lot of small holes here."
    
    scene den_07
    
    d "Can satyrs pick on a baby dragon? Can that be a thing?"

label den_choice_d:
    
    scene page
    
    menu:
        
        d "Poor Ysa's being bullied by the satyrs...there's gotta be a way they can help her..."
        
        "Comfort Ysa":
            $ ysa_done = True
            $ mother = True
            jump comfort
        
        "Tell her about Satyr's fears" if fear == True:
            $ ysa_done = True
            $ mother = True
            jump gossip
            
        "Rewrite Something":
            $ ysa_done = True
            jump den_menu

label comfort:
    
    scene den_08
    
    d "Always pet a dragon with caution."
    
    jump mother_info

label gossip:
    
    scene den_09
    
    d "Good girl Reina! You pass on that info!"
    
    jump mother_info

label mother_info:
    
    scene den_10
    
    d "Unfortunately you are..."
    
    scene blank
    
    d "Ok but now I have an idea of WHERE they'll meet the MOTHER!"
    
    menu:
        
        "Rewrite that Part...":
            jump den_menu

label entrance:
    
    scene den_11
    
    d "Come on, it's never THAT easy!"

label den_choice_b:
    
    scene page
    
    menu:
        
        d "An injured whelp...do they have something they could use to help? Or should they just make a break for it?"
        
        "Offer to Heal the Whelp" if salve == True:
            $ entrance_done = True
            jump healer
    
        "Run Past the Guard":
            $ ran = True
            $ entrance_done = True
            jump runner
            
        "Rewrite Something":
            $ entrance_done = True
            jump den_menu

label healer:
    
    scene den_12
    
    d "Dragons can totally get burned...I state it as so."
    
label den_choice_e:
    
    scene page
    
    menu:
        
        d "We're in...now where should we go?"
        
        "Go Up to the Nesting Chambers" if mother == True:
            $ den_done = True
            $ betrayed = True
            jump traitor
        
        "Continue down to where the injured whelp is":
            $ string_woman = True
            $ den_done = True
            jump honest
        
        "Rewrite Something":
            $ den_done = True
            jump den_menu

label traitor:
    
    scene den_13
    
    d "One hard boiled princess coming right up!"
    
    scene blank
    
    d "..."
    d "...you can't kill the herione in a childrens' book..."
    d "Maybe I should turn the heater down so I stop thinking about fire..."
    
    menu:
        
        "Rewrite that Part...":
            jump den_menu

label honest:
    
    scene den_14
    
    d "She's lucky that dragon didn't just attack her on the spot"
    
    scene den_15
    
    d "WOMAN WITH THE STRINGS...ok I've got an idea I think we're almost at the end here!"
    
    if mother == True:
    
        jump have_info
    
    if mother == False:
    
        jump need_more

label need_more:
    
    scene den_16
    
    d "Not a very close family..."
    
    scene blank
    
    d "Ok wait I need to know where they're keeping the mother...where I'm keeping the mother...you know what I mean..."
    
    menu:
        
        "Rewrite That Part...":
            $ heal_done = True
            jump den_menu

label have_info:
    
    scene den_17
    
    d "Yep she's in the NESTING CHAMBERS!"
    
label den_choice_f:
    
    scene page
    
    menu:
        
        d "Do we know where the mother is? That's really important information."
            
        "Proceed to the Nesting Chambers" if mother == True:
            $ complete = True
            $ heal_done = True
            jump ending
        
        "Rewrite That Part...":
            $ heal_done = True
            jump den_menu
    
label runner:
    
    scene den_18
    
    d "...I feel heat building up..."
    
    scene blank
    
    d "OH NO! I left the oven on!"
    d "..."
    d "Ok, we're good...now where we we?"
    
    menu:
        
        "Rewrite that Part...":
            jump den_menu

label ending:
    
    scene end_01
    
    d "Oh wait! The dragon told us to ask her about something!"
    
    scene end_02
    
    d "Too heavy handed?"
    
    scene end_03
    
    d "So the moral of the story is: give people second chances. All kids stories have morals in em right?"
    
    scene end_04
    
    d "...I want to fly home on a dragon..."
    
    scene end_05
    
    d "Huzzah!"
    
    scene blank
    
    d "I did it!"
    d "It's done!"
    d "Phew I've got plenty of time to edit and clean it up before the deadline too."
    "*ring* *ring*"
    d "Hm? Who's calling me? My editor?! What does he want now?"
    d "Hello? Yes! Yes I just finished it I-"
    d "Huh?"
    d "What do you mean you want a story about time travel???"
    
    "THE END...?"
    
    return
    
label rewind_menu:
    
    call screen storymap

label sea_menu:
    
    call screen sea_map

label wood_menu:
    
    call screen wood_map

label stone_menu:
    
    call screen stone_map

label den_menu:
    
    call screen den_map